[Gmp-commit] /var/hg/gmp: 4 new changesets
mercurial at gmplib.org
mercurial at gmplib.org
Sun Oct 23 21:09:22 CEST 2011
details: /var/hg/gmp/rev/c2958100f213
changeset: 14374:c2958100f213
user: Torbjorn Granlund <tege at gmplib.org>
date: Sun Oct 23 21:03:20 2011 +0200
description:
Use llgfr for zero extensions.
details: /var/hg/gmp/rev/3aa4b581b887
changeset: 14375:3aa4b581b887
user: Torbjorn Granlund <tege at gmplib.org>
date: Sun Oct 23 21:05:22 2011 +0200
description:
Add s390_64 sqr_basecase, remove integrated sqr_diag_addlsh1 code.
details: /var/hg/gmp/rev/11298c12a36e
changeset: 14376:11298c12a36e
user: Torbjorn Granlund <tege at gmplib.org>
date: Sun Oct 23 21:08:58 2011 +0200
description:
Add s390_64 mul_basecase.
details: /var/hg/gmp/rev/a66368f7f3e7
changeset: 14377:a66368f7f3e7
user: Torbjorn Granlund <tege at gmplib.org>
date: Sun Oct 23 21:09:15 2011 +0200
description:
*** empty log message ***
diffstat:
ChangeLog | 7 +
mpn/s390_64/mod_34lsub1.asm | 14 +-
mpn/s390_64/mul_basecase.asm | 119 ++++++++++++++++++++++
mpn/s390_64/sqr_basecase.asm | 202 +++++++++++++++++++++++++++++++++++++++
mpn/s390_64/sqr_diag_addlsh1.asm | 77 --------------
5 files changed, 332 insertions(+), 87 deletions(-)
diffs (truncated from 465 to 300 lines):
diff -r 1d60286bb006 -r a66368f7f3e7 ChangeLog
--- a/ChangeLog Sun Oct 23 02:23:26 2011 +0200
+++ b/ChangeLog Sun Oct 23 21:09:15 2011 +0200
@@ -1,5 +1,12 @@
2011-10-23 Torbjorn Granlund <tege at gmplib.org>
+ * mpn/s390_64/mod_34lsub1.asm: Use llgfr for zero extensions.
+
+ * mpn/s390_64/mul_basecase.asm: New file.
+
+ * mpn/s390_64/sqr_basecase.asm: New file.
+ * mpn/s390_64/sqr_diag_addlsh1.asm: Removed, lives on in sqr_basecase.
+
* mpn/s390_64/bdiv_dbm1c.asm: Shave off 1 c/l.
* mpn/s390_64/aorrlsh1_n.asm: New file, developed from aorslsh1_n.asm.
diff -r 1d60286bb006 -r a66368f7f3e7 mpn/s390_64/mod_34lsub1.asm
--- a/mpn/s390_64/mod_34lsub1.asm Sun Oct 23 02:23:26 2011 +0200
+++ b/mpn/s390_64/mod_34lsub1.asm Sun Oct 23 21:09:15 2011 +0200
@@ -35,8 +35,7 @@
ASM_START()
PROLOGUE(mpn_mod_34lsub1)
- stmg %r7, %r13, 56(%r15)
- larl %r13, .L12
+ stmg %r7, %r12, 56(%r15)
lghi %r11, 0
lghi %r12, 0
lghi %r0, 0
@@ -82,10 +81,10 @@
agr %r0, %r1
srlg %r1, %r10, 32
agr %r0, %r1
- ng %r12, .L14-.L12(%r13)
+ llgfr %r12, %r12
srlg %r1, %r9, 16
sllg %r12, %r12, 16
- ng %r10, .L14-.L12(%r13)
+ llgfr %r10, %r10
agr %r0, %r1
llill %r2, 65535
agr %r0, %r12
@@ -94,11 +93,6 @@
agr %r0, %r10
sllg %r2, %r2, 32
agr %r2, %r0
- lmg %r7, %r13, 56(%r15)
+ lmg %r7, %r12, 56(%r15)
br %r14
EPILOGUE()
-
- RODATA
- ALIGN(8)
-.L12:
-.L14: .quad 4294967295
diff -r 1d60286bb006 -r a66368f7f3e7 mpn/s390_64/mul_basecase.asm
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/mpn/s390_64/mul_basecase.asm Sun Oct 23 21:09:15 2011 +0200
@@ -0,0 +1,119 @@
+dnl S/390-64 mpn_mul_basecase.
+
+dnl Copyright 2011 Free Software Foundation, Inc.
+
+dnl This file is part of the GNU MP Library.
+
+dnl The GNU MP Library is free software; you can redistribute it and/or modify
+dnl it under the terms of the GNU Lesser General Public License as published
+dnl by the Free Software Foundation; either version 3 of the License, or (at
+dnl your option) any later version.
+
+dnl The GNU MP Library is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
+dnl License for more details.
+
+dnl You should have received a copy of the GNU Lesser General Public License
+dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
+
+include(`../config.m4')
+
+C cycles/limb
+C z900 ?
+C z990 23
+C z9 ?
+C z10 ?
+C z196 ?
+
+C TODO
+C * Perhaps add special case for un <= 2.
+C * Replace loops by faster code. The mul_1 and addmul_1 loops could be sped
+C up by about 10%.
+
+C INPUT PARAMETERS
+define(`rp', `%r2')
+define(`up', `%r3')
+define(`un', `%r4')
+define(`vp', `%r5')
+define(`vn', `%r6')
+
+define(`zero', `%r8')
+
+ASM_START()
+PROLOGUE(mpn_mul_basecase)
+ cghi un, 2
+ jhe L(ge2)
+
+C un = vn = 1
+ lg %r1, 0(vp)
+ mlg %r0, 0(up)
+ stg %r1, 0(rp)
+ stg %r0, 8(rp)
+ br %r14
+
+L(ge2): C jne L(gen)
+
+
+L(gen):
+C mul_1 =======================================================================
+
+ stmg %r6, %r12, 48(%r15)
+ lghi zero, 0
+ aghi un, -1
+
+ lg %r7, 0(vp)
+ lg %r11, 0(up)
+ lghi %r12, 8 C init index register
+ mlgr %r10, %r7
+ lgr %r9, un
+ stg %r11, 0(rp)
+ cr %r15, %r15 C clear carry flag
+
+L(tm): lg %r1, 0(%r12,up)
+ mlgr %r0, %r7
+ alcgr %r1, %r10
+ lgr %r10, %r0 C copy high part to carry limb
+ stg %r1, 0(%r12,rp)
+ la %r12, 8(%r12)
+ brctg %r9, L(tm)
+
+ alcgr %r0, zero
+ stg %r0, 0(%r12,rp)
+
+C addmul_1 loop ===============================================================
+
+ aghi vn, -1
+ je L(outer_end)
+L(outer_loop):
+
+ la rp, 8(rp) C rp += 1
+ la vp, 8(vp) C up += 1
+ lg %r7, 0(vp)
+ lg %r11, 0(up)
+ lghi %r12, 8 C init index register
+ mlgr %r10, %r7
+ lgr %r9, un
+ alg %r11, 0(rp)
+ stg %r11, 0(rp)
+
+L(tam): lg %r1, 0(%r12,up)
+ lg %r11, 0(%r12,rp)
+ mlgr %r0, %r7
+ alcgr %r1, %r11
+ alcgr %r0, zero
+ algr %r1, %r10
+ lgr %r10, %r0
+ stg %r1, 0(%r12,rp)
+ la %r12, 8(%r12)
+ brctg %r9, L(tam)
+
+ alcgr %r0, zero
+ stg %r0, 0(%r12,rp)
+
+ brctg vn, L(outer_loop)
+L(outer_end):
+
+ lmg %r6, %r12, 48(%r15)
+ br %r14
+EPILOGUE()
diff -r 1d60286bb006 -r a66368f7f3e7 mpn/s390_64/sqr_basecase.asm
--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/mpn/s390_64/sqr_basecase.asm Sun Oct 23 21:09:15 2011 +0200
@@ -0,0 +1,202 @@
+dnl S/390-64 mpn_sqr_basecase.
+
+dnl Copyright 2011 Free Software Foundation, Inc.
+
+dnl This file is part of the GNU MP Library.
+
+dnl The GNU MP Library is free software; you can redistribute it and/or modify
+dnl it under the terms of the GNU Lesser General Public License as published
+dnl by the Free Software Foundation; either version 3 of the License, or (at
+dnl your option) any later version.
+
+dnl The GNU MP Library is distributed in the hope that it will be useful, but
+dnl WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+dnl or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
+dnl License for more details.
+
+dnl You should have received a copy of the GNU Lesser General Public License
+dnl along with the GNU MP Library. If not, see http://www.gnu.org/licenses/.
+
+include(`../config.m4')
+
+C cycles/limb
+C z900 ?
+C z990 23
+C z9 ?
+C z10 ?
+C z196 ?
+
+C TODO
+C * Clean up.
+C * Stop iterating addmul_1 loop at latest for n = 2, implement longer tail.
+C This will ask for basecase handling of n = 3.
+C * Update counters and pointers more straightforwardly, possibly lowering
+C register usage.
+C * Should we use this allocation-free style for more sqr_basecase asm
+C implementations? The only disadvantage is that it requires R != U.
+C * Replace loops by faster code. The mul_1 and addmul_1 loops could be sped
+C up by about 10%. The sqr_diag_addlsh1 loop could probably be sped up even
+C more.
+
+C INPUT PARAMETERS
+define(`rp', `%r2')
+define(`up', `%r3')
+define(`n', `%r4')
+
+define(`zero', `%r8')
+define(`rp_saved', `%r9')
+define(`up_saved', `%r13')
+define(`n_saved', `%r14')
+
+ASM_START()
+PROLOGUE(mpn_sqr_basecase)
+ aghi n, -2
+ jhe L(ge2)
+
+C n = 1
+ lg %r5, 0(up)
+ mlgr %r4, %r5
+ stg %r5, 0(rp)
+ stg %r4, 8(rp)
+ br %r14
+
+L(ge2): jne L(gen)
+
+C n = 2
+ stmg %r6, %r8, 48(%r15)
+ lghi zero, 0
+
+ lg %r5, 0(up)
+ mlgr %r4, %r5 C u0 * u0
+ lg %r1, 8(up)
+ mlgr %r0, %r1 C u1 * u1
+ stg %r5, 0(rp)
+
+ lg %r7, 0(up)
+ mlg %r6, 8(up) C u0 * u1
+ algr %r7, %r7
+ alcgr %r6, %r6
+ alcgr %r0, zero
+
+ algr %r4, %r7
+ alcgr %r1, %r6
+ alcgr %r0, zero
+ stg %r4, 8(rp)
+ stg %r1, 16(rp)
+ stg %r0, 24(rp)
+
+ lmg %r6, %r8, 48(%r15)
+ br %r14
+
+L(gen):
+C mul_1 =======================================================================
+
+ stmg %r6, %r14, 48(%r15)
+ lghi zero, 0
+ lgr up_saved, up
+ lgr rp_saved, rp
+ lgr n_saved, n
+
+ lg %r6, 0(up)
+ lg %r11, 8(up)
+ lghi %r12, 16 C init index register
+ mlgr %r10, %r6
+ lgr %r5, n
+ stg %r11, 8(rp)
+ cr %r15, %r15 C clear carry flag
+
+L(tm): lg %r1, 0(%r12,up)
+ mlgr %r0, %r6
+ alcgr %r1, %r10
+ lgr %r10, %r0 C copy high part to carry limb
+ stg %r1, 0(%r12,rp)
+ la %r12, 8(%r12)
+ brctg %r5, L(tm)
+
+ alcgr %r0, zero
+ stg %r0, 0(%r12,rp)
+
More information about the gmp-commit
mailing list